写了个汇编连连看给网友们玩玩
Tofloor
poster avatar
gzw
deepin
2016-10-18 21:04
Author
;;;;;;;;;;;;;;;;;;;;;;;;;;
;汇编连连看
;1084字节
;作者老光头
;2016年10月
;nasm编译
;方向键操作移动光标
;回车键选择
;ESC键开始新游戏
;;;;;;;;;;;;;;;;;;;;;;;;;;
org 100h
kaishi:
                call        ditu
                mov                ax,0xb800
                mov                es,ax
                mov                ax,0
                int                10h
                mov                dx,0x0707
                call        xianshi
;;;;;;;;;;;;;;;键盘
jianpan:
        mov                ah,2
        mov                bh,0
        int                10h       
        qujianpan:
                MOV AH, 01h       
                int                16h       
                jnz                dujianpan
                jmp                qujianpan
        dujianpan:
                mov                ax,10000111b
                int                16h
                key1:       
                cmp ah,0x4b
                jne                key2
                dec                dl
                cmp                dl,2
                jnl                key2               
                mov                dl,13
                key2:       
                cmp ah,0x4d
                jne                key3
                inc                dl
                cmp                dl,14
                jl                key3               
                mov                dl,2
                key3:       
                cmp ah,0x48
                jne                key4
                dec                dh
                cmp                dh,2
                jnl                key4               
                mov                dh,13
                key4:       
                cmp ah,0x50
                jne                key5
                inc                dh
                cmp                dh,14
                jl                key5               
                mov                dh,2
                key5:       
                cmp ah,0x1c
                jne                key6
                call        chuli
                key6:
                cmp ah,0x1
                jne                key0
                jmp                kaishi
                key0:
                mov                ah,2
                mov                bh,0
                int                10h
                jmp                jianpan
;;;×××××××××××××××××××××××××××××××××××子程序
;;;;;;;;;;;随机地图
ditu:
        pusha
                mov                cx,0
                mov                bx,32
        ditu1:
                call        suijishu
                movzx                si,al
                call        suijishu
                movzx                di,al
                mov                ah,[show+si+bx]
                mov                al,[show+di+bx]
                mov                [show+si+bx],al
                mov                [show+di+bx],ah
                add                bx,16
                cmp                bx,16*15
                jle                ditu2
                mov                bx,32
                ditu2:
                inc                cx
                cmp                cx,0xff
                jl                ditu1
                popa
                ret
;;;;;;;;;;;;随机数
suijishu:
                push        cx
                push        dx
                push        bx
                in                al,40h
                mov                ah,0
                mov                bl,12
                div                bl
                add                ah,2
                mov                al,ah
                pop                bx
                pop                dx
                pop                cx
                ret
;;;;;;;;;;;;;;;;;;fka
fka:
        pusha
        ;复制fkax到fkbx
        mov                cx,16
        mov                si,fkax
        mov                di,fkbx
        fka2:
        mov                ah,[si]
        mov                bh,[si+16]
        cmp                al,[ys]        ;与上次点击图形相同
        je                fka3
        mov                ah,0xfe
        mov                bh,ah
        fka3:
        mov                [di+16],bh
        mov                [di],ah
        inc                di
        inc                si
        loop        fka2
                ;生成fkax
push        dx
                mov                si,fkax
                mov                dl,0
        fka1:
                        mov                ah,2
                        mov                bh,0
                        int                10h
                        mov                ah,8
                        mov                bh,0
                        int                10h
                        mov                [si],al
                inc                dl
                inc                si
                cmp                si,fkax+16
                jl                fka1
pop                dx
                ;生成fkay
                mov                si,fkay
                mov                dh,0
        fka5:
                        mov                ah,2
                        mov                bh,0
                        int                10h
                        mov                ah,8
                        mov                bh,0
                        int                10h
                        mov                [si],al
                inc                dh
                inc                si
                cmp                si,fkay+16
                jl                fka5
        fka0:
        popa
        call        panduanx
        call        panduany
        ret
;;;;;;;;;;;;;;;;;判断x
panduanx:
        pusha
        ;;;;;分析fkax左
        mov                ah,0
        movzx        bx,dl
        pd1:
        mov                [fkax+bx],ah
        cmp                bx,0
        je                pd2
        dec                bx       
        mov                cl,[fkax+bx]
        cmp                cl,0
        je                pd1
        mov                ah,0xfe
        jmp                pd1
        ;;;;;;;分析fkbx右
        pd2:
        mov                ah,0
        movzx        bx,dl
        pd3:
        mov                [fkax+bx],ah
        cmp                bx,15
        je                pd9
        inc                bx       
        mov                cl,[fkax+bx]
        cmp                cl,0
        je                pd3
        mov                ah,0xfe
        jmp                pd3
        pd9:
        ;;;;;分析fkzy
        mov                bx,0
        pd8:
        mov                al,[fkax+bx]
        movzx                si,al
        mov                al,[fkbx+bx]
        movzx                di,al
        or                si,di
        cmp                si,0
        jne                pd7
        movzx        si,dh        ;取行1
        mov                ax,[qd]        ;取行2
        movzx        di,ah
        cmp                si,di        ;比较行
        jl                pd4
        xchg        si,di        ;交换行
        pd4:
        sub                di,si
        dec                di
        inc                si
        mov                ax,si
        shl                ax,6
        shl                si,4
        add                si,ax
        mov                al,0        ;z值
                pd5:
                cmp                di,0
                je                pd6
                dec         di
                shl                bx,1
                or                al,[es:si+bx]        ;z值累计
                shr                bx,1
                add                si,80        ;下一行
                jmp                pd5       
        pd6:       
                cmp                al,0        ;是否畅通
                jne                pd7                ;阻碍
                mov                al,0xfe
                mov                [ys],al
                jmp                pd0
        pd7:
        inc                bx        ;下一z
        cmp                bx,16
        jl                pd8
        pd0:
        popa
ret
;;;;;;;;;;;;;;;;;判断y
panduany:
        pusha
        ;;;;;分析fkay上
        mov                ah,0
        movzx        bx,dh
        pdy1:
        mov                [fkay+bx],ah
        cmp                bx,0
        je                pdy2
        dec                bx       
        mov                cl,[fkay+bx]
        cmp                cl,0
        je                pdy1
        mov                ah,0xfe
        jmp                pdy1
        ;;;;;;;分析fkby下
        pdy2:
        mov                ah,0
        movzx        bx,dh
        pdy3:
        mov                [fkay+bx],ah
        cmp                bx,15
        je                pdy9
        inc                bx       
        mov                cl,[fkay+bx]
        cmp                cl,0
        je                pdy3
        mov                ah,0xfe
        jmp                pdy3
        pdy9:
        ;;;;;分析fkzy
        mov                bp,0
        pdy8:
        mov                bx,bp
        mov                al,[fkay+bx]
        movzx        si,al
        mov                al,[fkby+bx]
        movzx        di,al
        or                si,di
        cmp                si,0
        jne                pdy7
        movzx        si,dl        ;取列1
        mov                ax,[qd]        ;取列2
        movzx        di,al
        cmp                si,di        ;比较列
        jl                pdy4
        xchg        si,di        ;交换列
        pdy4:
        sub                di,si
        dec                di
        inc                si
        mov                ax,bx
        shl                ax,6
        shl                bx,4
        add                bx,ax
        mov                al,0        ;z值
                pdy5:
                cmp                di,0
                je                pdy6
                dec         di
                shl                si,1
                or                al,[es:bx+si]        ;z值累计
                shr                si,1
                add                si,1        ;下一列
                jmp                pdy5       
        pdy6:       
                cmp                al,0        ;是否畅通
                jne                pdy7                ;阻碍
                mov                al,0xfe
                mov                [ys],al
                jmp                pdy0
        pdy7:
        inc                bp        ;下一z
        cmp                bp,16
        jl                pdy8
        pdy0:
        popa
ret
;;;;;;;;;;;;;;;;;;处理
chuli:
                pusha
                call        shan
                mov                ah,2
                mov                bh,0
                int                10h
                mov                ah,8
                mov                bh,0
                int                10h
                call        fka
                mov                ah,0xfe
                cmp                ah,[ys]
                je                chuli1
                mov                [ys],al
                mov                [qd],dx
                call        shan
                jmp                chuli0
        chuli1:
                mov                ah,2
                mov                bh,0
                int                10h
                mov        ax,0x0900
                mov         bx,7
                mov                cx,1
                int                10h
                mov                dx,[qd]
                mov                ah,2
                mov                bh,0
                int                10h
                mov        ax,0x0900
                mov         bx,7
                mov                cx,1
                int                10h
                mov                al,0xff
                mov                [ys],al
                mov                ax,0x0101
                mov                [qd],ax
        chuli0:
                popa
                ret
;;;;;;;;;;;;;;;闪
shan:
                pusha
                mov                dx,[qd]
                mov                ah,2
                mov                bh,0
                int                10h
                mov                ah,8
                mov                bh,0
                int                10h
                mov                bl,ah
                xor                bl,10000000b
                mov        ah,9
                mov                cx,1
                int                10h
                popa
                ret
;;;;;;;;;;;;;;;显示
xianshi:
                pusha
                mov                si,0
                mov                ax,0
                mov                ch,0
        xianshix:
                mov                cl,0
                xianshiy:
                        mov                al,[show+si]
                        mov                ah,00000111b
                        mov                [es:bx],ax
                        add                bx,2
                        add                cl,1
                        add                si,1
                cmp                cl,16
                jl                xianshiy
                add                bx,48
                add                ch,1
        cmp                ch,16
        jl                xianshix
        popa
        ret
;;;************************************数据
show:
                db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
                db        219,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,234,003,004,005,006,232,001,009,233,011,012,014,  0,219
                db        219,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,  0,219
                db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
fkax:        db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
fkay:        db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
fkbx:        db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
fkby:        db        219,219,219,219,219,219,219,219,219,219,219,219,219,219,219,219
qd:                dw        0x0101
ys:                db        0xff
Reply Favorite View the author
All Replies
avatar
左心房的痛
deepin
2016-10-18 21:25
#1
大神,你又开始写汇编了??请问在linux下如何使用?
Reply View the author
avatar
gzw
deepin
2016-10-18 21:28
#2
https://bbs.deepin.org/post/44649
大神,你又开始写汇编了??请问在linux下如何使用?

在linux上安装一个dosbox,现在dosbox里运行,附件中有编译好得com文件
因为是用16位写得
Reply View the author
avatar
kaisawind
deepin
2016-11-10 06:57
#3
这是wdos版的汇编
linux也是支持汇编的
但是linux默认是AT&T风格的。
intel风格的虽然也支持、但是跟windows的比总是怪怪的。

然后这还是32位系统的汇编...
Reply View the author