写了个462字节的俄罗斯方块,分享一下。
Tofloor
poster avatar
gzw
deepin
2016-10-13 18:56
Author
;附件中有带详细注解的源代码已经编译好的com文件,由于发帖文章大小的限制,这里贴一下无注解的源代码,具体的在附件中。


;;;;;;;;;;;;;;;;;;;;;;;;;;
;462字节俄罗斯方块
;作者老光头
;2016年10月
;nasm编译
;方向键操作
;;;;;;;;;;;;;;;;;;;;;;;;;;


org    100h    ;此行打开,编译成16位dos的com文件
;org    7c00h    ;此行打开,编译成mbr引导

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;程序入口:
        mov        ax,0xb800
        mov        es,ax         
        call    kongbeijing     
        call    xinfangkuai     

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;键盘
jianpan:
ziyouxailuo:     
        mov        ah,0
        int        1ah         
        mov        al,00000111b
        and        al,dl     
        cmp        al,0     
        je        noxfkh     
        dec        al         
        shl        al,3     
        mov        [xfkh],al     
    noxfkh:
        shr        dx,4         
        cmp        dl,[shijian]
        jne        qushijian     
        jmp        qujianpan     
qushijian:
        mov        [shijian],dx     
        mov        ah,0x50            
        jmp        jianpanchuli     
         
qujianpan:            
        MOV AH, 01h     
        int        16h     
        jnz        dujianpan
        jmp        jianpan     
    dujianpan:
        mov        ah,0h
        int        16h         
         
    jianpanchuli:            
        mov        al,[fkh]     
        mov        bx,[fkx]     

        key1:     
        cmp ah,0x4b
        jne        key2
        dec        bl

        key2:     
        cmp ah,0x4d
        jne        key3
        inc        bl
         
        key3:     
        cmp ah,0x48
        jne        key4
        mov        dl,al     
        mov        dh,al
        add        dl,2
        and        dl,00000111b
        and        al,11111000b
        or        al,dl     
                 
        key4:     
        cmp ah,0x50
        jne        key0
        inc        bh         
         
        key0:     
        call    chuli
        mov        [fkh],al     
        mov        [fkx],bx     

    jmp jianpan                 

         
;*****************************************子程序***********************************

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;空背景
kongbeijing:
        pusha
        mov        ax,0000h
        INT        10H            
        mov        cx,16
        mov        si,2         
        mov        di,2         
        mov        al,219         
    show:     
        mov        [es:di],al     
        mov        [es:di+32],al     
        mov        [es:si+80*15],al     
        add        di,80         
        add        si,2
        loop    show         
        popa
        ret

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;新方块
xinfangkuai:
        mov        bx,7     
        mov        al,[xfkh]     
        mov        [fkh],al     
        mov        [fkx],bx     
        mov        ah,2         
        call    fangkuaixianshi     
        ret         

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;按键后的处理
chuli:
        pusha
        mov        al,[fkh]         
        mov        bx,[fkx]         
        mov        ah,1            
        call    fangkuaixianshi     
        popa
        mov        ah,3            
        call    fangkuaixianshi     
        mov        ch,[pz]            
        cmp        ch,0            
        je        wupengzhuang     
        cmp        bh,[fky]         
        je        zuoyou                 
        mov        ch,2            
    zuoyou:
        mov        al,[fkh]         
        mov        bx,[fkx]         

    wupengzhuang:     
        mov        ah,2            
        call    fangkuaixianshi     
        cmp        ch,2            
        jne        chulijieshu         
        call    manhang            
        cmp        bh,0            
        jne        laoyouxi         
        call    kongbeijing         
    laoyouxi:
        call    xinfangkuai         
    chulijieshu:
        ret
         
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;满行
manhang:
        pusha
        mov        dx,16
        mov        si,0
        manhangx:                        
            mov        bx,4
            manhangy:                     
                mov        al,[es:si+bx]     
                cmp        al,219            
                jne        manhangz         
            add        bx,2                 
            cmp        bx,34                 
            jl        manhangy
            
            pusha
                mov        ah,7h
                mov        al,1
                mov        bh,7
                mov        ch,0
                mov        cl,2
                int 10h                     
            popa
            
        manhangz:
        inc        dh                     
        add        si,80
        cmp        dh,15                     
        jne        manhangx                 
        popa
        ret


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;方块显示处理
fangkuaixianshi:
        pusha
            push    ax
            movzx    si,al
            mov        si,[fangkuai+si]     
            mov        al,80
            mul        bh
            mov        bh,0
            shl        bl,1
            add        ax,bx
            mov        di,ax                 
            mov        bp,1000000000000000b     
            
            mov        ch,0     
            mov        [pz],ch     
            pop        ax
            xianshix:
                mov        cl,0     
                xianshiy:     
                    mov        dx,si     
                    and        dx,bp     

                a3:         
                    cmp        ah,3
                    jne        a1
                    cmp        dx,0     
                    je        a9
                    mov        al,[es:di]
                    cmp        al,219     
                    jne        a9         
                    mov        al,1
                    mov        [pz],al         
                    jmp        a9

                a1:         
                    cmp        dx,0
                    je        a9
                    mov        al,0     
                    cmp        ah,1     
                    je        xieping
                    mov        al,219     
                    xieping:
                    mov        [es:di],al     

                a9:
                    add     di,2         
                    shr        bp,1         
                    inc        cl            
                    cmp        cl,4
                jne        xianshiy
                inc        ch                 
                add        di,72            
                cmp        ch,4            
            jne        xianshix

        popa
        ret

;******************************************数据******************************************
;方块图形数据
fangkuai:
;山
    dw 0100111000000000b
    dw 0100011001000000b
    dw 0000111001000000b
    dw 0100110001000000b
;L
    dw 0100010001100000b
    dw 0000111010000000b
    dw 0110001000100000b
    dw 0010111000000000b
;J
    dw 0100010011000000b
    dw 1000111000000000b
    dw 0110010001000000b
    dw 0000111000100000b
;;上
    dw 0010011001000000b
    dw 1100011000000000b
    dw 0010011001000000b
    dw 1100011000000000b
     
;;下
    dw 0100011000100000b
    dw 0110110000000000b
    dw 0100011000100000b
    dw 0110110000000000b

;;|
    dw 0100010001000100b
    dw 0000111100000000b
    dw 0100010001000100b
    dw 0000111100000000b
;;口
    dw 0110011000000000b
    dw 0110011000000000b
    dw 0110011000000000b
    dw 0110011000000000b

pz:        db    0    ;碰撞标志
fkx:    db     0    ;方块位置
fky:    db     0    ;方块位置
fkh:    db     0    ;方块图形
shijian    db    0    ;当前时间
xfkh    db    0    ;随机方块
;TIMES     510 - ($ - $$)  DB  0    ;此行打开,编译成mbr引导
;db 0x55,0xaa    ;此行打开,编译成mbr引导




Reply Favorite View the author
All Replies
avatar
jingle
deepin
2016-10-13 19:06
#1
Reply View the author
avatar
moli3
deepin
2016-10-13 19:15
#2
汇编写的,厉害了
Reply View the author
avatar
lzh1104
deepin
2016-10-13 19:19
#3
不会玩。~
Reply View the author
avatar
探索
deepin
2016-10-13 19:27
#4
好久没见过汇编代码了,真厉害!
Reply View the author
avatar
山西姚一
deepin
2016-10-13 19:30
#5
不明觉厉ing……
Reply View the author
avatar
左心房的痛
deepin
2016-10-13 22:40
#6
大神,竟然用汇编语言
Reply View the author
avatar
jyehc
deepin
2016-10-14 03:42
#7
汇编。。。看不懂。。。瞻仰一下
Reply View the author
avatar
ghostry
deepin
2016-10-14 04:26
#8
现在还在用汇编的都是大爷大妈级别的。楼主暴露年龄了。
Reply View the author
avatar
chinagz
deepin
2016-10-14 04:53
#9
不明觉厉
Reply View the author
avatar
gzw
deepin
2016-10-14 20:15
#10
;修正了一个bug,字节数缩减为460字节

;;;;;;;;;;;;;;;;;;;;;;;;;;
;460字节俄罗斯方块
;作者老光头
;2016年10月
;nasm编译
;方向键操作
;;;;;;;;;;;;;;;;;;;;;;;;;;


org        100h        ;此行打开,编译成16位dos的com文件
;org        7c00h        ;此行打开,编译成mbr引导

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;程序入口:
                mov                ax,0xb800
                mov                es,ax               
                call        kongbeijing       
                call        xinfangkuai       

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;键盘
jianpan:
ziyouxailuo:       
                mov                ah,0
                int                1ah               
                mov                al,00000111b
                and                al,dl       
                cmp                al,0       
                je                noxfkh       
                dec                al               
                shl                al,3       
                mov                [xfkh],al       
        noxfkh:
                shr                dx,4               
                cmp                dl,[shijian]
                jne                qushijian       
                jmp                qujianpan       
qushijian:
                mov                [shijian],dx       
                mov                ah,0x50                       
                jmp                jianpanchuli       
               
qujianpan:                       
                MOV AH, 01h       
                int                16h       
                jnz                dujianpan
                jmp                jianpan       
        dujianpan:
                mov                ah,0h
                int                16h               
               
        jianpanchuli:                       
                mov                al,[fkh]       
                mov                bx,[fkx]       

                key1:       
                cmp ah,0x4b
                jne                key2
                dec                bl

                key2:       
                cmp ah,0x4d
                jne                key3
                inc                bl
               
                key3:       
                cmp ah,0x48
                jne                key4
                mov                dl,al       
                add                dl,2
                and                dl,00000111b
                and                al,11111000b
                or                al,dl       
                               
                key4:       
                cmp ah,0x50
                jne                key0
                inc                bh               
               
                key0:       
                call        chuli
                mov                [fkh],al       
                mov                [fkx],bx       

        jmp jianpan                               

               
;*****************************************子程序***********************************

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;空背景
kongbeijing:
                pusha
                mov                ax,0000h
                INT                10H                       
                mov                cx,16
                mov                si,2               
                mov                di,2               
                mov                al,219               
        show:       
                mov                [es:di],al       
                mov                [es:di+32],al       
                mov                [es:si+80*15],al       
                add                di,80               
                add                si,2
                loop        show               
                popa
                ret

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;新方块
xinfangkuai:
                mov                bx,7       
                mov                al,[xfkh]       
                mov                [fkh],al       
                mov                [fkx],bx       
                mov                ah,2               
                call        fangkuaixianshi       
                ret               

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;按键后的处理
chuli:
                pusha
                mov                al,[fkh]               
                mov                bx,[fkx]               
                mov                ah,1                       
                call        fangkuaixianshi       
                popa
                mov                ah,3                       
                call        fangkuaixianshi       
                mov                ch,[pz]                       
                cmp                ch,0                       
                je                wupengzhuang       
                cmp                bh,[fky]               
                je                zuoyou                               
                mov                ch,2                       
        zuoyou:
                mov                al,[fkh]               
                mov                bx,[fkx]               

        wupengzhuang:       
                mov                ah,2                       
                call        fangkuaixianshi       
                cmp                ch,2                       
                jne                chulijieshu               
                call        manhang                       
                cmp                bh,0                       
                jne                laoyouxi               
                call        kongbeijing               
        laoyouxi:
                call        xinfangkuai               
        chulijieshu:
                ret
               
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;满行
manhang:
                pusha
                mov                dx,16
                mov                si,0
                manhangx:                                               
                        mov                bx,4
                        manhangy:                                       
                                mov                al,[es:si+bx]       
                                cmp                al,219                       
                                jne                manhangz               
                        add                bx,2                               
                        cmp                bx,34                               
                        jl                manhangy
                       
                        pusha
                                mov                ah,7h
                                mov                al,1
                                mov                bh,7
                                mov                ch,0
                                mov                cl,2
                                int 10h                                       
                        popa
                       
                manhangz:
                inc                dh                                       
                add                si,80
                cmp                dh,15                                       
                jne                manhangx                               
                popa
                ret


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;方块显示处理
fangkuaixianshi:
                pusha
                        push        ax
                        movzx        si,al
                        mov                si,[fangkuai+si]       
                        mov                al,80
                        mul                bh
                        mov                bh,0
                        shl                bl,1
                        add                ax,bx
                        mov                di,ax                               
                        mov                bp,1000000000000000b       
                       
                        mov                ch,0       
                        mov                [pz],ch       
                        pop                ax
                        xianshix:
                                mov                cl,0       
                                xianshiy:       
                                        mov                dx,si       
                                        and                dx,bp       

                                a3:               
                                        cmp                ah,3
                                        jne                a1
                                        cmp                dx,0       
                                        je                a9
                                        mov                al,[es:di]
                                        cmp                al,219       
                                        jne                a9               
                                        mov                al,1
                                        mov                [pz],al               
                                        jmp                a9

                                a1:               
                                        cmp                dx,0
                                        je                a9
                                        mov                al,0       
                                        cmp                ah,1       
                                        je                xieping
                                        mov                al,219       
                                        xieping:
                                        mov                [es:di],al       

                                a9:
                                        add         di,2               
                                        shr                bp,1               
                                        inc                cl                       
                                        cmp                cl,4
                                jne                xianshiy
                                inc                ch                               
                                add                di,72                       
                                cmp                ch,4                       
                        jne                xianshix

                popa
                ret

;******************************************数据******************************************
;方块图形数据
fangkuai:
;山
        dw 0100111000000000b
        dw 0100011001000000b
        dw 0000111001000000b
        dw 0100110001000000b
;L
        dw 0100010001100000b
        dw 0000111010000000b
        dw 0110001000100000b
        dw 0010111000000000b
;J
        dw 0100010011000000b
        dw 1000111000000000b
        dw 0110010001000000b
        dw 0000111000100000b
;;上
        dw 0010011001000000b
        dw 1100011000000000b
        dw 0010011001000000b
        dw 1100011000000000b
       
;;下
        dw 0100011000100000b
        dw 0110110000000000b
        dw 0100011000100000b
        dw 0110110000000000b

;;|
        dw 0100010001000100b
        dw 0000111100000000b
        dw 0100010001000100b
        dw 0000111100000000b
;;口
        dw 0110011000000000b
        dw 0110011000000000b
        dw 0110011000000000b
        dw 0110011000000000b

pz:                db        0        ;碰撞标志
fkx:        db         0        ;方块位置
fky:        db         0        ;方块位置
fkh:        db         0        ;方块图形
shijian        db        0        ;当前时间
xfkh        db        0        ;随机方块
;TIMES     510 - ($ - $$)  DB  0        ;此行打开,编译成mbr引导
;db 0x55,0xaa        ;此行打开,编译成mbr引导


Reply View the author
avatar
jhsunnyshine
deepin
2016-10-14 22:34
#11
膜拜了。。。。
Reply View the author
avatar
Smokey Joe
deepin
2016-10-14 22:52
#12
膜拜大神,现在那些面向对象的统统面壁去吧。
Reply View the author
avatar
wdm3g
deepin
2016-10-14 22:58
#13
服了,彻底的服了,您那汇编用的真溜。
Reply View the author
avatar
usckur
deepin
2016-10-15 00:32
#14
惭愧大学没学好单片机。膜拜大神。
Reply View the author
avatar
司南
deepin
2016-11-19 21:15
#15
膜拜大神,佩服,佩服
Reply View the author
avatar
189******23
deepin
2016-11-20 04:24
#16
。。。这是汇编吧。。
给跪了
Reply View the author
avatar
随风
deepin
2016-11-20 19:11
#17
赞赞赞!
Reply View the author
avatar
cuixiaofei
deepin
2016-11-20 21:44
#18
腻害呀,编程了得
Reply View the author
avatar
185******15
deepin
2016-11-20 21:54
#19
本帖最后由 ginanony 于 2016-11-20 13:56 编辑

厉害呀,我的哥。。。。。


弱弱的请教linux下玩汇编的指导教材。。。。



Reply View the author